Playground Error: Stream error: Unexpected token (29:29)

[w1531724247]

Error Message:
Stream error: Unexpected token (29:29)

Code:

//
// @author LazyBear 
// List of all my indicators: https://www.tradingview.com/v/4IneGo8h/
//
study(shorttitle = "SQZMOM_LB", title="Squeeze Momentum Indicator [LazyBear]", overlay=false)

length = input(20, title="BB Length")
mult = input(2.0,title="BB MultFactor")
lengthKC=input(20, title="KC Length")
multKC = input(1.5, title="KC MultFactor")

useTrueRange = input(true, title="Use TrueRange (KC)", type=bool)

// Calculate BB
source = close
basis = sma(source, length)
dev = multKC * stdev(source, length)
upperBB = basis + dev
lowerBB = basis - dev

// Calculate KC
ma = sma(source, lengthKC)
range = useTrueRange ? tr : (high - low)
rangema = sma(range, lengthKC)
upperKC = ma + rangema * multKC
lowerKC = ma - rangema * multKC

sqzOn  = (lowerBB > lowerKC) and (upperBB < upperKC)
sqzOff = (lowerBB < lowerKC) and (upperBB > upperKC)
noSqz  = (sqzOn == false) and (sqzOff == false)

val = linreg(source  -  avg(avg(highest(high, lengthKC), lowest(low, lengthKC)),sma(close,lengthKC)), 
            lengthKC,0)

bcolor = iff( val > 0, 
            iff( val > nz(val[1]), lime, green),
            iff( val < nz(val[1]), red, maroon))
scolor = noSqz ? blue : sqzOn ? black : gray 
plot(val, color=bcolor, style=histogram, linewidth=4)
plot(0, color=scolor, style=cross, linewidth=2)

Browser: Mozilla/5.0 (Macintosh; Intel Mac OS X 10_15_7) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/146.0.0.0 Safari/537.36

[alaa-eddine]

hi @w1531724247

This code uses study() which is from older Pine Script versions.
PineTS supports Pine Script v5 and v6.

here is an equivalent code converted to v6 that should work fine ;)

//@version=6
indicator(shorttitle="SQZMOM_LB", title="Squeeze Momentum Indicator [LazyBear]", overlay=false)

length      = input.int(20, title="BB Length")
mult        = input.float(2.0, title="BB MultFactor")
lengthKC    = input.int(20, title="KC Length")
multKC      = input.float(1.5, title="KC MultFactor")
useTrueRange = input.bool(true, title="Use TrueRange (KC)")

// Calculate BB
source  = close
basis   = ta.sma(source, length)
dev     = mult * ta.stdev(source, length)
upperBB = basis + dev
lowerBB = basis - dev

// Calculate KC
ma      = ta.sma(source, lengthKC)
range_  = useTrueRange ? ta.tr : (high - low)
rangema = ta.sma(range_, lengthKC)
upperKC = ma + rangema * multKC
lowerKC = ma - rangema * multKC

sqzOn   = (lowerBB > lowerKC) and (upperBB < upperKC)
sqzOff  = (lowerBB < lowerKC) and (upperBB > upperKC)
noSqz   = not sqzOn and not sqzOff

val = ta.linreg(
    source - math.avg(math.avg(ta.highest(high, lengthKC), ta.lowest(low, lengthKC)), ta.sma(close, lengthKC)),
    lengthKC,
    0
)

bcolor = val > 0
    ? (val > nz(val[1]) ? color.lime : color.green)
    : (val < nz(val[1]) ? color.red : color.maroon)

scolor = noSqz ? color.blue : sqzOn ? color.black : color.gray

plot(val, color=bcolor, style=plot.style_histogram, linewidth=4)
plot(0, color=scolor, style=plot.style_cross, linewidth=2)