build.gradle

plugins {
    id 'net.fabricmc.fabric-loom' version '1.16-SNAPSHOT'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "2.+"
    id "io.github.themrmilchmann.curseforge-publish" version "0.9.0"
}

version = project.mod_version
group = project.maven_group

loom {
    accessWidenerPath = file("src/main/resources/embeddedcomputer.classtweaker")
}

base {
    archivesName = project.archives_base_name
}


repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.
    maven {
        url = "https://maven.squiddev.cc"
        content {
            includeGroup("cc.tweaked")
        }
    }
    maven { url = "https://maven.shedaniel.me" }
    exclusiveContent {
        forRepository {
            maven {
                name = "Modrinth"
                url = "https://api.modrinth.com/maven"
            }
        }
        filter {
            includeGroup "maven.modrinth"
        }
    }

    maven {
        name 'Xander Maven'
        url 'https://maven.isxander.dev/releases'
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    //ComputerCraft
    compileOnly "cc.tweaked:cc-tweaked-${project.minecraft_version}-fabric-api:$cctVersion"
    implementation "cc.tweaked:cc-tweaked-${project.minecraft_version}-fabric:$cctVersion"

    testImplementation 'com.google.code.findbugs:jsr305:3.0.2'

    implementation "dev.isxander:yet-another-config-lib:${project.yacl_version}"
}

processResources {
    inputs.property "version", project.version
    inputs.property "minecraft_version", project.minecraft_version
    inputs.property "loader_version", project.loader_version
    inputs.property "cctVersion", project.cctVersion
    filteringCharset = "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "minecraft_version": project.minecraft_version,
                "loader_version": project.loader_version,
                "cctVersion": project.cctVersion
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 25
}

java {
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_25
    targetCompatibility = JavaVersion.VERSION_25
}

jar {
    from("LICENSE.txt") {
        rename { "${it}_${inputs.properties.archivesName}" }
    }
}

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}

modrinth {
    token = System.getenv("MODRINTH_TOKEN")// Remember to have the MODRINTH_TOKEN environment variable set or else this will fail - just make sure it stays private!
    projectId = "embeddedcomputer" // This can be the project ID or the slug. Either will work!
    versionNumber = "${project.version}" // You don't need to set this manually. Will fail if Modrinth has this version already
    versionType = "release" // This is the default -- can also be `beta` or `alpha`
    uploadFile = jar // With Loom, this MUST be set to `remapJar` instead of `jar`!
    gameVersions = ["${project.minecraft_version}"] // Must be an array, even with only one version
    dependencies { // A special DSL for creating dependencies
        required.project "fabric-api"
        required.project "cc-tweaked"
        required.project "yacl"
    }
}
curseforge {
    apiToken = System.getenv("CURSEFORGE_TOKEN")
    publications {
        named("fabric") {
            projectId = "1519384"
            artifacts.named("main") {
                projectId = "1519384"
                displayName = "Embedded Computer ${project.version}"
                relations {
                    requiredDependency("yacl")
                    requiredDependency("fabric-api")
                }
            }
        }
    }
}

tasks.register('remapJar') {
    dependsOn 'jar'
    outputs.file(project.buildDir.absolutePath.concat("/libs/embeddedcomputer-${project.version}.jar"))
}