A few CMake improvements (#68)

- Set the SONAME on the library to generate correct symlinks
- Set visibility of inline functions to hidden (didn't use CMake since
this library is linux only)
- Use the built-in LTO detection mechanism instead of rolling my own

Author: marcomagdy

CMakeLists.txt

@@ -1,14 +1,12 @@
-cmake_minimum_required(VERSION 3.5)
+cmake_minimum_required(VERSION 3.9)
 set(CMAKE_CXX_STANDARD 11)
 project(aws-lambda-runtime
     VERSION 0.2.4
     LANGUAGES CXX)
 
 option(ENABLE_TESTS "Enables building the test project, requires AWS C++ SDK." OFF)
 
-include(CheckCXXCompilerFlag)
-
-check_cxx_compiler_flag("-Wl,-flto" LTO_CAPABLE)
+include(CheckIPOSupported)
 
 add_library(${PROJECT_NAME}
     "src/logging.cpp"
@@ -17,12 +15,21 @@ add_library(${PROJECT_NAME}
     "${CMAKE_CURRENT_BINARY_DIR}/version.cpp"
     )
 
-set_target_properties(${PROJECT_NAME} PROPERTIES VERSION ${PROJECT_VERSION})
+set_target_properties(${PROJECT_NAME} PROPERTIES
+    SOVERSION 0
+    VERSION ${PROJECT_VERSION})
 
 target_include_directories(${PROJECT_NAME} PUBLIC
     $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
     $<INSTALL_INTERFACE:include>)
 
+check_ipo_supported(RESULT has_lto OUTPUT lto_check_output)
+if(has_lto)
+    set_property(TARGET ${PROJECT_NAME} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
+else()
+    message(WARNING "Link-time optimization (LTO) is not supported: ${lto_check_output}")
+endif()
+
 find_package(CURL REQUIRED)
 if (CMAKE_VERSION VERSION_LESS 3.12)
     target_link_libraries(${PROJECT_NAME} PRIVATE ${CURL_LIBRARIES})
@@ -36,6 +43,7 @@ target_compile_options(${PROJECT_NAME} PRIVATE
     "-fno-exceptions"
     "-fno-rtti"
     "-fvisibility=hidden"
+    "-fvisibility-inlines-hidden"
     "-Wall"
     "-Wextra"
     "-Werror"
@@ -64,11 +72,6 @@ else ()
     target_compile_definitions(${PROJECT_NAME} PRIVATE "AWS_LAMBDA_LOG=0")
 endif()
 
-if ((BUILD_SHARED_LIBS) AND (LTO_CAPABLE))
-    target_compile_options(${PROJECT_NAME} PRIVATE "-flto")
-    target_link_libraries(${PROJECT_NAME} PRIVATE "-flto")
-endif()
-
 #tests
 if (ENABLE_TESTS)
     enable_testing()
@@ -81,24 +84,37 @@ configure_file(
     "${CMAKE_CURRENT_BINARY_DIR}/version.cpp"
     NEWLINE_STYLE LF)
 
+include (CMakePackageConfigHelpers)
+
+write_basic_package_version_file("${PROJECT_NAME}-config-version.cmake"
+    VERSION ${PROJECT_VERSION}
+    COMPATIBILITY SameMajorVersion)
+
 # installation
 install(FILES "include/aws/http/response.h"
     DESTINATION "include/aws/http")
 
-install(FILES 
+install(FILES
     "include/aws/lambda-runtime/runtime.h"
     "include/aws/lambda-runtime/version.h"
     "include/aws/lambda-runtime/outcome.h"
-    DESTINATION "include/aws/lambda-runtime")
+    DESTINATION "include/aws/lambda-runtime"
+    COMPONENT ${PROJECT_NAME}-Development)
 
 install(FILES "include/aws/logging/logging.h"
     DESTINATION "include/aws/logging")
 
+include(GNUInstallDirs)
 install(TARGETS ${PROJECT_NAME}
     EXPORT ${PROJECT_NAME}-targets
-    ARCHIVE DESTINATION lib
-    LIBRARY DESTINATION lib
-    RUNTIME DESTINATION bin)
+    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    COMPONENT ${PROJECT_NAME}-Development
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    COMPONENT ${PROJECT_NAME}-Runtime
+    NAMELINK_COMPONENT ${PROJECT_NAME}-Developemnt
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    COMPONENT ${PROJECT_NAME}-Runtime
+    )
 
 configure_file("${CMAKE_SOURCE_DIR}/cmake/${PROJECT_NAME}-config.cmake"
     "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
@@ -111,6 +127,7 @@ install(EXPORT "${PROJECT_NAME}-targets"
     NAMESPACE AWS::)
 
 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
+    ${PROJECT_NAME}-config-version.cmake
     DESTINATION "lib/${PROJECT_NAME}/cmake/")
 
 install(PROGRAMS "${CMAKE_SOURCE_DIR}/packaging/packager"