java-client/build.gradle at master · goshawkdb/java-client · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
apply plugin: 'java'
apply plugin: 'java-library-distribution'
apply plugin: 'jacoco'
apply plugin: 'maven'

version = '0.3.1'
group = 'io.goshawkdb'
archivesBaseName = "goshawkdb-client"

sourceCompatibility = 1.8
targetCompatibility = 1.8

javadoc {
    source = {
        fileTree(dir: 'src/main/java/io/goshawkdb/client',
                includes: ['Certs.java', 'Connection.java', 'ConnectionFactory.java', 'Capability.java',
                           'GoshawkObjRef.java', 'Transaction.java', 'TransactionFunction.java',
                           'TransactionAbortedException.java',
                           'TransactionResult.java', 'TxnId.java', 'VarUUId.java'])
    }
}

jar {
    manifest {
        from('MANIFEST.MF')
        attributes("Specification-Version": version,
                "Implementation-Version": version)
    }
    into('META-INF') {
        from('LICENSE')
    }
}

distributions {
    main {
        contents {
            from('LICENSE')
        }
    }
}

jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination "${buildDir}/jacocoHtml"
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://localhost/tmp/myRepo/")
            pom.project {
                name 'GoshawkDB Java Client'
                packaging 'jar'
                description 'The Java Client for GoshawkDB'
                url = 'https://goshawkdb.io/'

                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }

                developers {
                    developer {
                        name = 'Matthew Sackman'
                        email = 'matthew@goshawkdb.io'
                        organization = 'GoshawkDB'
                        organizationUrl = 'https://goshawkdb.io/'
                    }
                }

                scm {
                    connection 'scm:hg:https://src.goshawkdb.io/java-client/'
                    developerConnection 'scm:hg:https://src.goshawkdb.io/java-client/'
                    url 'https://src.goshawkdb.io/java-client/'
                }
            }
        }
    }
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
    manifest {
        from jar.manifest
    }
    into('META-INF') {
        from('LICENSE')
    }
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
    manifest {
        from jar.manifest
    }
    into('META-INF') {
        from('LICENSE')
    }
}

artifacts {
    archives javadocJar, sourcesJar
}

test {
    maxParallelForks = 1
    environment(
            'GOSHAWKDB_DEFAULT_CLUSTER_HOSTS': 'localhost',
            'GOSHAWKDB_DEFAULT_CLUSTER_CERT': projectDir.path.concat('/src/test/resources/defaultClusterCert.pem'),
            'GOSHAWKDB_DEFAULT_CLIENT_KEYPAIR': projectDir.path.concat('/src/test/resources/defaultClientKeyPair.pem'),
            'GOSHAWKDB_DEFAULT_ROOT_NAME': 'test'
    )
}

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.capnproto', name: 'runtime', version: '0.1.1'
    compile group: 'io.netty', name: 'netty-all', version: '4.1.6.Final'
    compile group: 'org.bouncycastle', name: 'bcpkix-jdk15on', version: '1.55'
    compile group: 'commons-codec', name: 'commons-codec', version: '1.10'
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

configurations {
    testFixtures
}

task testFixturesJar(type: Jar) {
    classifier = 'tests'
    from sourceSets.test.output
}

artifacts {
    testFixtures testFixturesJar
}