QtCipherSqlitePlugin/sqlitecipher.pro at main · mxrcode/QtCipherSqlitePlugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
TARGET = sqlitecipher

android {
    TEMPLATE = app
} else {
    TEMPLATE = lib
}

QT += core core-private sql sql-private
QT_FOR_CONFIG += sqldrivers-private

CONFIG += c++11 plugin

include($$PWD/src/sqlite3/sqlite3.pri)

target.path = $$[QT_INSTALL_PLUGINS]/sqldrivers/
INSTALLS += target

HEADERS  += \
    $$PWD/src/sqlitecipher_p.h \
    $$PWD/src/sqlitecipher_global.h

SOURCES  += \
    $$PWD/src/main.cpp \
    $$PWD/src/sqlitecipher.cpp

OTHER_FILES += $$PWD/src/SqliteCipherDriverPlugin.json

!system-sqlite:!contains( LIBS, .*sqlite.* ) {
    CONFIG(release, debug|release):DEFINES *= NDEBUG
    DEFINES += SQLITE_OMIT_LOAD_EXTENSION \
               SQLITE_OMIT_COMPLETE \
               SQLITE_ENABLE_FTS3 \
               SQLITE_ENABLE_FTS3_PARENTHESIS \
               SQLITE_ENABLE_RTREE \
               SQLITE_USER_AUTHENTICATION
    !contains(CONFIG, largefile):DEFINES += SQLITE_DISABLE_LFS
    winrt: DEFINES += SQLITE_OS_WINRT
    winphone: DEFINES += SQLITE_WIN32_FILEMAPPING_API=1
    qnx: DEFINES += _QNX_SOURCE
} else {
    LIBS += $$QT_LFLAGS_SQLITE
    QMAKE_CXXFLAGS *= $$QT_CFLAGS_SQLITE
}

PLUGIN_CLASS_NAME = SqliteCipherDriverPlugin
PLUGIN_TYPE = sqldrivers

DEFINES += QT_NO_CAST_TO_ASCII QT_NO_CAST_FROM_ASCII

QMAKE_CFLAGS += -march=native