Add VAT rate resolution and VAT amount difference for E-Document purchases

src/Apps/W1/EDocument/App/src/Extensions/EDocPurchPayablesSetup.PageExt.al

@@ -26,6 +26,16 @@ pageextension 6162 "E-Doc. Purch. Payables Setup" extends "Purchases & Payables
                 ApplicationArea = All;
                 ToolTip = 'Specifies how the posting date is set on purchase invoices created from e-documents. Work Date uses the current work date. Document Date uses the document date from the e-document.';
             }
+            field("Apply VAT Diff. For Purch EDoc"; Rec."Apply VAT Diff. For Purch EDoc")
+            {
+                ApplicationArea = All;
+                ToolTip = 'Specifies whether VAT difference should be applied when matching incoming E-Document line with Purchase Order line';
+            }
+            field("Resolve VAT Group Purch EDoc"; Rec."Resolve VAT Group Purch EDoc")
+            {
+                ApplicationArea = All;
+                ToolTip = 'Specifies whether to resolve VAT Product Group for purchase lines created from e-documents based on the VAT rate and the vendor''s VAT posting setup. If disabled, the VAT Product Group will not be identified based on the purchase e-document.';
+            }
         }
     }
 }

src/Apps/W1/EDocument/App/src/Extensions/EDocPurchPayablesSetup.TableExt.al

@@ -26,5 +26,17 @@ tableextension 6162 "E-Doc. Purch. Payables Setup" extends "Purchases & Payables
             Caption = 'E-Document Default Posting Date';
             DataClassification = CustomerContent;
         }
+        field(6103; "Apply VAT Diff. For Purch EDoc"; Boolean)
+        {
+            Caption = 'Apply VAT Diff. For Purch. E-Doc.';
+            DataClassification = CustomerContent;
+            InitValue = true;
+        }
+        field(6104; "Resolve VAT Group Purch EDoc"; Boolean)
+        {
+            Caption = 'Resolve VAT Product Group for Purch. E-Doc.';
+            DataClassification = CustomerContent;
+            InitValue = true;
+        }
     }
 }

src/Apps/W1/EDocument/App/src/Processing/Import/FinishDraft/EDocCreatePurchaseInvoice.Codeunit.al

@@ -178,6 +178,7 @@ codeunit 6117 "E-Doc. Create Purchase Invoice" implements IEDocumentFinishDraft,
         EDocLineByReceipt.Close();
         PurchaseHeader.Modify();
         PurchCalcDiscByType.ApplyInvDiscBasedOnAmt(EDocumentPurchaseHeader."Total Discount", PurchaseHeader);
+        EDocPurchaseDocumentHelper.ApplyVATDifferenceToLines(PurchaseHeader, EDocumentPurchaseHeader);
         exit(PurchaseHeader);
     end;
 

src/Apps/W1/EDocument/App/src/Processing/Import/FinishDraft/EDocPurchDocHelper.Codeunit.al

@@ -7,7 +7,9 @@ namespace Microsoft.eServices.EDocument.Processing.Import;
 using Microsoft.eServices.EDocument;
 using Microsoft.eServices.EDocument.Processing;
 using Microsoft.eServices.EDocument.Processing.Import.Purchase;
+using Microsoft.Finance.Currency;
 using Microsoft.Finance.Dimension;
+using Microsoft.Finance.VAT.Setup;
 using Microsoft.Foundation.Attachment;
 using Microsoft.Purchases.Document;
 using Microsoft.Purchases.Posting;
@@ -40,6 +42,9 @@ codeunit 6402 "E-Doc. Purch. Doc. Helper"
         PurchaseLine."Variant Code" := EDocumentPurchaseLine."[BC] Variant Code";
         PurchaseLine.Type := EDocumentPurchaseLine."[BC] Purchase Line Type";
         ValidateFieldWithContext(PurchaseLine, PurchaseLine.FieldNo("No."), EDocumentPurchaseLine."[BC] Purchase Type No.");
+        if EDocumentPurchaseLine."[BC] VAT Prod. Posting Group" <> '' then
+            ValidateFieldWithContext(
+                PurchaseLine, PurchaseLine.FieldNo("VAT Prod. Posting Group"), EDocumentPurchaseLine."[BC] VAT Prod. Posting Group");
         if (PurchaseLine.Type = PurchaseLine.Type::"G/L Account") and HasTotalDiscount then
             ValidateFieldWithContext(PurchaseLine, PurchaseLine.FieldNo("Allow Invoice Disc."), true);
         PurchaseLine.Description := EDocumentPurchaseLine.Description;
@@ -154,6 +159,45 @@ codeunit 6402 "E-Doc. Purch. Doc. Helper"
         EDocImpSessionTelemetry.SetBool('Totals Validation', TryValidateDocumentTotals(PurchaseHeader));
     end;
 
+    procedure ApplyVATDifferenceToLines(PurchaseHeader: Record "Purchase Header"; EDocumentPurchaseHeader: Record "E-Document Purchase Header")
+    var
+        PurchaseLine: Record "Purchase Line";
+        Currency: Record Currency;
+        LineAmount: Decimal;
+        TotalLineAmount, VATDiffRemainder, VATDiffForLine : Decimal;
+        AppliedVATAmountDiff: Decimal;
+    begin
+        AppliedVATAmountDiff := EDocumentPurchaseHeader.GetAppliedVATAmountDiff();
+        if AppliedVATAmountDiff = 0 then
+            exit;
+
+        if PurchaseHeader."Currency Code" = '' then
+            Currency.InitRoundingPrecision()
+        else
+            Currency.Get(PurchaseHeader."Currency Code");
+
+        TotalLineAmount := ComputeTotalLineAmount(EDocumentPurchaseHeader."E-Document Entry No.", Currency."Amount Rounding Precision");
+        if TotalLineAmount = 0 then
+            exit;
+
+        PurchaseLine.SetRange("Document Type", PurchaseHeader."Document Type");
+        PurchaseLine.SetRange("Document No.", PurchaseHeader."No.");
+        PurchaseLine.SetFilter(Type, '<>%1', PurchaseLine.Type::" ");
+        if not PurchaseLine.FindSet() then
+            exit;
+
+        VATDiffRemainder := 0;
+        repeat
+            LineAmount := PurchaseLine."Line Amount" - PurchaseLine."Inv. Discount Amount";
+            if LineAmount <> 0 then begin
+                VATDiffForLine := VATDiffRemainder + AppliedVATAmountDiff * LineAmount / TotalLineAmount;
+                PurchaseLine.Validate("VAT Difference", Round(VATDiffForLine, Currency."Amount Rounding Precision"));
+                VATDiffRemainder := VATDiffForLine - PurchaseLine."VAT Difference";
+                PurchaseLine.Modify(true);
+            end;
+        until PurchaseLine.Next() = 0;
+    end;
+
     procedure RevertCreatedDocument(EDocument: Record "E-Document")
     var
         PurchaseHeader: Record "Purchase Header";
@@ -181,4 +225,27 @@ codeunit 6402 "E-Doc. Purch. Doc. Helper"
             exit;
         PurchaseHeader.Validate("Posting Date", EDocumentPurchaseHeader."Document Date");
     end;
+
+    procedure SetNormalReverseChargeFilter(var VATPostingSetup: Record "VAT Posting Setup"; VATBusPostingGroup: Code[20])
+    begin
+        VATPostingSetup.SetRange("VAT Bus. Posting Group", VATBusPostingGroup);
+        VATPostingSetup.SetFilter("VAT Calculation Type", '%1|%2',
+            VATPostingSetup."VAT Calculation Type"::"Normal VAT",
+            VATPostingSetup."VAT Calculation Type"::"Reverse Charge VAT");
+    end;
+
+    local procedure ComputeTotalLineAmount(EDocEntryNo: Integer; AmountRoundingPrecision: Decimal): Decimal
+    var
+        EDocPurchLine: Record "E-Document Purchase Line";
+        TotalLineAmount: Decimal;
+    begin
+        EDocPurchLine.SetRange("E-Document Entry No.", EDocEntryNo);
+        if EDocPurchLine.FindSet() then
+            repeat
+                TotalLineAmount += Round(
+                    EDocPurchLine.Quantity * EDocPurchLine."Unit Price" - EDocPurchLine."Total Discount",
+                    AmountRoundingPrecision);
+            until EDocPurchLine.Next() = 0;
+        exit(TotalLineAmount);
+    end;
 }

src/Apps/W1/EDocument/App/src/Processing/Import/PrepareDraft/EDocPreparePurchDraft.Codeunit.al

@@ -8,8 +8,11 @@ using Microsoft.eServices.EDocument;
 using Microsoft.eServices.EDocument.Processing.AI;
 using Microsoft.eServices.EDocument.Processing.Import.Purchase;
 using Microsoft.eServices.EDocument.Processing.Interfaces;
+using Microsoft.Finance.GeneralLedger.Setup;
+using Microsoft.Finance.VAT.Setup;
 using Microsoft.Foundation.UOM;
 using Microsoft.Purchases.Document;
+using Microsoft.Purchases.Setup;
 using Microsoft.Purchases.Vendor;
 using System.Log;
 
@@ -31,11 +34,15 @@ codeunit 6406 "EDoc Prepare Purch. Draft"
         Vendor: Record Vendor;
         PurchaseOrder: Record "Purchase Header";
         EDocVendorAssignmentHistory: Record "E-Doc. Vendor Assign. History";
+
         EDocPurchaseHistMapping: Codeunit "E-Doc. Purchase Hist. Mapping";
         EDocActivityLogSession: Codeunit "E-Doc. Activity Log Session";
         IUnitOfMeasureProvider: Interface IUnitOfMeasureProvider;
         IPurchaseLineProvider: Interface IPurchaseLineProvider;
         IPurchaseOrderProvider: Interface IPurchaseOrderProvider;
+        LineAmount: Decimal;
+        LineVATAmount: Decimal;
+        TotalLineVATAmount: Decimal;
     begin
         IUnitOfMeasureProvider := EDocImportParameters."Processing Customizations";
         IPurchaseLineProvider := EDocImportParameters."Processing Customizations";
@@ -72,16 +79,26 @@ codeunit 6406 "EDoc Prepare Purch. Draft"
                     EDocumentPurchaseLine.Modify();
                 until EDocumentPurchaseLine.Next() = 0;
 
+            // Resolve VAT Product Posting Groups from extracted VAT rates
+            ResolveVATProductPostingGroups(EDocument."Entry No", EDocumentPurchaseHeader);
+
             CopilotLineMatching(EDocument."Entry No");
         end;
 
         Clear(EDocumentPurchaseLine);
         EDocumentPurchaseLine.SetRange("E-Document Entry No.", EDocument."Entry No");
+        TotalLineVATAmount := 0;
         if EDocumentPurchaseLine.FindSet() then
             repeat
+                LineAmount := Round(EDocumentPurchaseLine.Quantity * EDocumentPurchaseLine."Unit Price" - EDocumentPurchaseLine."Total Discount");
+                LineVATAmount := Round(LineAmount * EDocumentPurchaseLine."VAT Rate" / 100);
+                TotalLineVATAmount += LineVATAmount;
                 EDocImpSessionTelemetry.SetLine(EDocumentPurchaseLine.SystemId);
             until EDocumentPurchaseLine.Next() = 0;
 
+        ComputeAndApplyVATAmountDifference(EDocumentPurchaseHeader, TotalLineVATAmount);
+        EDocumentPurchaseHeader.Modify();
+
         LogAllActivitySessionChanges(EDocActivityLogSession);
 
         if EDocActivityLogSession.EndSession() then;
@@ -138,6 +155,72 @@ codeunit 6406 "EDoc Prepare Purch. Draft"
             ActivityLog.Log();
     end;
 
+    local procedure ResolveVATProductPostingGroups(EDocumentEntryNo: Integer; EDocumentPurchaseHeader: Record "E-Document Purchase Header")
+    var
+        PurchasesPayablesSetup: Record "Purchases & Payables Setup";
+        EDocumentPurchaseLine: Record "E-Document Purchase Line";
+        Vendor: Record Vendor;
+        VATRate: Decimal;
+        LineBase: Decimal;
+        LineCount: Integer;
+    begin
+        if not PurchasesPayablesSetup.Get() then
+            exit;
+        if not PurchasesPayablesSetup."Resolve VAT Group Purch EDoc" then
+            exit;
+        Vendor := EDocumentPurchaseHeader.GetBCVendor();
+        if Vendor."No." = '' then
+            exit;
+        if Vendor."VAT Bus. Posting Group" = '' then
+            exit;
+
+        EDocumentPurchaseLine.SetRange("E-Document Entry No.", EDocumentEntryNo);
+        LineCount := EDocumentPurchaseLine.Count();
+        if LineCount = 0 then
+            exit;
+
+        if EDocumentPurchaseLine.FindSet() then
+            repeat
+                VATRate := EDocumentPurchaseLine."VAT Rate";
+
+                // Single-line fallback: compute from header Total VAT
+                if (VATRate = 0) and (LineCount = 1) and (EDocumentPurchaseHeader."Total VAT" > 0) then begin
+                    LineBase := EDocumentPurchaseLine.Quantity * EDocumentPurchaseLine."Unit Price" - EDocumentPurchaseLine."Total Discount";
+                    if LineBase = 0 then
+                        LineBase := EDocumentPurchaseHeader."Sub Total";
+                    if LineBase > 0 then
+                        VATRate := Round((EDocumentPurchaseHeader."Total VAT" / LineBase) * 100, 0.01);
+                end;
+
+                if VATRate > 0 then begin
+                    EDocumentPurchaseLine."[BC] VAT Prod. Posting Group" :=
+                        FindVATProductPostingGroup(Vendor."VAT Bus. Posting Group", VATRate);
+                    EDocumentPurchaseLine.Modify();
+                    if EDocumentPurchaseLine."[BC] VAT Prod. Posting Group" = '' then
+                        EDocumentPurchaseLine.LogVATRateMismatch(Vendor."VAT Bus. Posting Group", VATRate)
+                    else
+                        EDocumentPurchaseLine.LogVATRateResolved(Vendor."VAT Bus. Posting Group", VATRate);
+                end;
+            until EDocumentPurchaseLine.Next() = 0;
+    end;
+
+    local procedure FindVATProductPostingGroup(VATBusPostingGroup: Code[20]; VATRate: Decimal): Code[20]
+    var
+        VATPostingSetup: Record "VAT Posting Setup";
+        EDocPurchDocHelper: Codeunit "E-Doc. Purch. Doc. Helper";
+        CustomDimensions: Dictionary of [Text, Text];
+        VATPostingGroupNotFoundLbl: Label 'VAT Product Posting Group not found for VAT Rate %1.', Comment = '%1 = VAT rate', Locked = true;
+    begin
+        EDocPurchDocHelper.SetNormalReverseChargeFilter(VATPostingSetup, VATBusPostingGroup);
+        VATPostingSetup.SetRange("VAT %", VATRate);
+        if VATPostingSetup.Count() = 1 then begin
+            VATPostingSetup.FindFirst();
+            exit(VATPostingSetup."VAT Prod. Posting Group");
+        end;
+        Session.LogMessage('0000TXZ', StrSubstNo(VATPostingGroupNotFoundLbl, VATRate), Verbosity::Warning, DataClassification::SystemMetadata, TelemetryScope::All, CustomDimensions);
+        exit('');
+    end;
+
     local procedure CopilotLineMatching(EDocumentEntryNo: Integer)
     var
         EDocumentPurchaseLine: Record "E-Document Purchase Line";
@@ -172,4 +255,64 @@ codeunit 6406 "EDoc Prepare Purch. Draft"
             if Codeunit.Run(Codeunit::"E-Doc. Deferral Matching", EDocumentPurchaseLine) then;
         end;
     end;
+
+    local procedure ComputeAndApplyVATAmountDifference(EDocumentPurchaseHeader: Record "E-Document Purchase Header"; TotalLineVATAmount: Decimal)
+    var
+        PurchasesPayablesSetup: Record "Purchases & Payables Setup";
+        GeneralLedgerSetup: Record "General Ledger Setup";
+        ActivityLog: Codeunit "Activity Log Builder";
+        VATAmountDiff: Decimal;
+        Reasoning: Text[250];
+        VATDiffAppliedLbl: Label 'Applied VAT amount difference of %1 to reconcile document Total VAT %2 with computed Total Line VAT Amount %3.', Comment = '%1 = VAT difference, %2 = Total VAT, %3 = Total Line VAT Amount';
+        VATDiffSkippedSetupLbl: Label 'VAT amount difference of %1 was not applied because Apply VAT Diff. For Purch. E-Doc. is disabled in Purchases & Payables Setup.', Comment = '%1 = VAT difference';
+        VATDiffSkippedAllowLbl: Label 'VAT amount difference of %1 was not applied because Allow VAT Difference is disabled in Purchases & Payables Setup.', Comment = '%1 = VAT difference';
+        VATDiffSkippedMaxLbl: Label 'VAT amount difference of %1 was not applied because it exceeds the Max. VAT Difference Allowed of %2 in General Ledger Setup.', Comment = '%1 = VAT difference, %2 = Max. VAT Difference Allowed';
+    begin
+        if (EDocumentPurchaseHeader."Total VAT" = 0) or (TotalLineVATAmount = EDocumentPurchaseHeader."Total VAT") then
+            exit;
+
+        VATAmountDiff := EDocumentPurchaseHeader."Total VAT" - TotalLineVATAmount;
+
+        if not PurchasesPayablesSetup.Get() then
+            exit;
+
+        if not PurchasesPayablesSetup."Apply VAT Diff. For Purch EDoc" then begin
+            Reasoning := CopyStr(StrSubstNo(VATDiffSkippedSetupLbl, VATAmountDiff), 1, MaxStrLen(Reasoning));
+            ActivityLog
+                .Init(Database::"E-Document Purchase Header", EDocumentPurchaseHeader.FieldNo("Total VAT"), EDocumentPurchaseHeader.SystemId)
+                .SetExplanation(Reasoning)
+                .SetType(Enum::"Activity Log Type"::"AL")
+                .Log();
+            exit;
+        end;
+
+        if not PurchasesPayablesSetup."Allow VAT Difference" then begin
+            Reasoning := CopyStr(StrSubstNo(VATDiffSkippedAllowLbl, VATAmountDiff), 1, MaxStrLen(Reasoning));
+            ActivityLog
+                .Init(Database::"E-Document Purchase Header", EDocumentPurchaseHeader.FieldNo("Total VAT"), EDocumentPurchaseHeader.SystemId)
+                .SetExplanation(Reasoning)
+                .SetType(Enum::"Activity Log Type"::"AL")
+                .Log();
+            exit;
+        end;
+
+        if not GeneralLedgerSetup.Get() then
+            exit;
+        if Abs(VATAmountDiff) > GeneralLedgerSetup."Max. VAT Difference Allowed" then begin
+            Reasoning := CopyStr(StrSubstNo(VATDiffSkippedMaxLbl, VATAmountDiff, GeneralLedgerSetup."Max. VAT Difference Allowed"), 1, MaxStrLen(Reasoning));
+            ActivityLog
+                .Init(Database::"E-Document Purchase Header", EDocumentPurchaseHeader.FieldNo("Total VAT"), EDocumentPurchaseHeader.SystemId)
+                .SetExplanation(Reasoning)
+                .SetType(Enum::"Activity Log Type"::"AL")
+                .Log();
+            exit;
+        end;
+
+        Reasoning := CopyStr(StrSubstNo(VATDiffAppliedLbl, VATAmountDiff, EDocumentPurchaseHeader."Total VAT", TotalLineVATAmount), 1, MaxStrLen(Reasoning));
+        ActivityLog
+            .Init(Database::"E-Document Purchase Header", EDocumentPurchaseHeader.FieldNo("Total VAT"), EDocumentPurchaseHeader.SystemId)
+            .SetExplanation(Reasoning)
+            .SetType(Enum::"Activity Log Type"::"AL")
+            .Log();
+    end;
 }

src/Apps/W1/EDocument/App/src/Processing/Import/Purchase/EDocPurchaseDraftSubform.Page.al

@@ -10,6 +10,7 @@ using Microsoft.Finance.Dimension;
 using Microsoft.Inventory.Item.Catalog;
 using Microsoft.Purchases.Document;
 using Microsoft.Purchases.History;
+using Microsoft.Purchases.Setup;
 
 page 6183 "E-Doc. Purchase Draft Subform"
 {
@@ -71,6 +72,12 @@ page 6183 "E-Doc. Purchase Draft Subform"
                     Lookup = true;
                     ShowMandatory = true;
                 }
+                field("VAT Prod. Posting Group"; Rec."[BC] VAT Prod. Posting Group")
+                {
+                    ApplicationArea = All;
+                    Lookup = true;
+                    Visible = VATProdPostGroupIsVisible;
+                }
                 field("Item Reference No."; Rec."[BC] Item Reference No.")
                 {
                     ApplicationArea = All;
@@ -333,7 +340,7 @@ page 6183 "E-Doc. Purchase Draft Subform"
         EDocPOMatching: Codeunit "E-Doc. PO Matching";
         AdditionalColumns, OrderMatchedCaption, MatchWarningsCaption, MatchWarningsStyleExpr : Text;
         LineAmount: Decimal;
-        DimVisible1, DimVisible2, HasAdditionalColumns, IsEDocumentMatchedToAnyPOLine, IsLineMatchedToOrderLine, IsLineMatchedToReceiptLine, HasEDocumentOrderMatchWarnings : Boolean;
+        DimVisible1, DimVisible2, HasAdditionalColumns, IsEDocumentMatchedToAnyPOLine, IsLineMatchedToOrderLine, IsLineMatchedToReceiptLine, HasEDocumentOrderMatchWarnings, VATProdPostGroupIsVisible : Boolean;
         HistoryCantBeRetrievedErr: Label 'The purchase invoice that matched historically with this line can''t be opened.';
 
     trigger OnOpenPage()
@@ -350,6 +357,7 @@ page 6183 "E-Doc. Purchase Draft Subform"
     trigger OnAfterGetCurrRecord()
     begin
         UpdatePOMatching();
+        SetVATProductPostingGroupVisibility();
     end;
 
     trigger OnAfterGetRecord()
@@ -362,6 +370,7 @@ page 6183 "E-Doc. Purchase Draft Subform"
         IsLineMatchedToReceiptLine := EDocPOMatching.IsEDocumentLineMatchedToAnyReceiptLine(EDocumentPurchaseLine);
         OrderMatchedCaption := IsLineMatchedToOrderLine ? GetSummaryOfMatchedOrders() : '';
         UpdateMatchWarnings();
+        SetVATProductPostingGroupVisibility();
     end;
 
     internal procedure SetEDocumentPurchaseHeader(EDocPurchHeader: Record "E-Document Purchase Header")
@@ -381,6 +390,14 @@ page 6183 "E-Doc. Purchase Draft Subform"
           DimVisible1, DimVisible2, DimOther, DimOther, DimOther, DimOther, DimOther, DimOther);
     end;
 
+    local procedure SetVATProductPostingGroupVisibility()
+    var
+        PurchSetup: Record "Purchases & Payables Setup";
+    begin
+        PurchSetup.Get();
+        VATProdPostGroupIsVisible := PurchSetup."Resolve VAT Group Purch EDoc";
+    end;
+
     local procedure UpdateCalculatedAmounts(UpdateParentRecord: Boolean)
     var
         TotalEDocPurchaseLine: Record "E-Document Purchase Line";
@@ -564,5 +581,4 @@ page 6183 "E-Doc. Purchase Draft Subform"
         if WarningDetails.Length() > 0 then
             Message(WarningDetails.ToText());
     end;
-
 }